/*
* @author Galaburda Oleg a_[w]
* http://actualwave.com/ 
*
*/

import aw.template.xml.MirrorList;
dynamic class aw.template.xml.XMLMirror extends Object{
	private var _attributes:Object;
	private var _children:Object;
	private var _name:String;
	private var _value:String;
	private var _parent:XMLMirror;
	private var _sequence:Array;
	function XMLMirror(x:Object, s:Boolean, p:XMLMirror){
		super();
		_parent = p;
		_children = new Object();
		_attributes = new Object();
		if(s) _sequence = new Array();
		parseXML((x instanceof XML) ? x.firstChild : XMLNode(x), s);
	}
	private function parseXML(x:XMLNode, s:Boolean):Void{
		for(var p:String in x.attributes) this._attributes[p] = x.attributes[p];
		var val:String = x.nodeValue ? x.nodeValue : '';
		var arr:Array = x.childNodes;
		var len:Number = arr.length;
		var name:String;
		var item:XMLNode;
		var mirror:XMLMirror;
		var list:MirrorList;
		for(var i:Number=0; i<len; i++){
			item = arr[i];
			if(item.nodeType==1){
				name = item.nodeName;
				list = this._children[name];
				if(!list) this._children[name] = list = new MirrorList();
				mirror = new XMLMirror(item, s, this);
				if(s) this._sequence.push(mirror);
				list.push(mirror);
			}else if(item.nodeType==3 && item.nodeValue) val += item.nodeValue;
		}
		this._name = x.nodeName;
		this._value = val;
	}
	public function getDescendants(name:String):MirrorList{
		var ret:MirrorList = new MirrorList();
		var rList:Array = ret.getList();
		for(var p:String in this._children){
			var arr:Array = this._children[p].getList();
			if(p==name && arr) rList.push.apply(rList, arr);
			var len:Number = arr.length;
			var item:XMLMirror;
			for(var i:Number=0; i<len; i++){
				item = arr[i];
				if(item) rList.push.apply(rList, item.getDescendants(name).getList());
			}
		}
		return ret;
	}
	public function getChildList():MirrorList{
		var ret:MirrorList = new MirrorList();
		if(this._sequence){
			ret.getList().push.apply(ret, this._sequence);
		}else{
			for(var p:String in this._children){
				ret.getList().push.apply(ret, this._children[p]);
			}
		}
		return ret;
	}
	public function getChildNames():Array{
		var ret:Array = new Array();
		for(var p:String in this._children){
			ret.push(p);
		}
		return ret;
	}
	public function get attributes():Object{
		return this._attributes;
	}
	public function get children():Object{
		return this._children;
	}
	public function getParent():XMLMirror{
		return this._parent;
	}
	public function getName():String{
		return this._name;
	}
	public function getValue():String{
		return this._value;
	}
	public function toString():String{
		return this._value;
	}
	public function __resolve(name:String):String{
		return this._attributes[name];
	}
	static public function create(x:XML, s:Boolean):XMLMirror{
		return new XMLMirror(x.firstChild, s, null);
	}
}