/*
* @author Galaburda Oleg a_[w]
* http://actualwave.com/ 
*
*/

package aw.xml.cover{
	import aw.utils.object_utils;
	import aw.xml.XMLNotifier;
	
	import flash.events.Event;
	import flash.events.IEventDispatcher;
	
	[Event(name="attributeAdded", type="aw.events.XMLEvent")]
	[Event(name="attributeChanged", type="aw.events.XMLEvent")]
	[Event(name="attributeRemoved", type="aw.events.XMLEvent")]
	[Event(name="nodeAdded", type="aw.events.XMLEvent")]
	[Event(name="nodeChanged", type="aw.events.XMLEvent")]
	[Event(name="nodeRemoved", type="aw.events.XMLEvent")]
	[Event(name="namespaceAdded", type="aw.events.XMLEvent")]
	[Event(name="namespaceRemoved", type="aw.events.XMLEvent")]
	[Event(name="namespaceSet", type="aw.events.XMLEvent")]
	[Event(name="textSet", type="aw.events.XMLEvent")]
	[Event(name="nameSet", type="aw.events.XMLEvent")]
	[Event(name="changed", type="aw.events.XMLEvent")]
	
	[Bindable("changed")]
	dynamic public class XMLCoverList extends XMLCoverProxy implements IEventDispatcher{
		protected var _list:XMLList;
		protected var _notifiers:Array;
		protected var _notifiersLength:int;
		public function XMLCoverList(l:XMLList=null, cTree:Boolean=true):void{
			_list = l ? l : new XMLList();
			super(_list, cTree);
			var len:int = _list.length();
		}
		object_utils function get list():XMLList{
			return this._list;
		}
		object_utils function get notifierList():Array{
			if(!this._notifiers) this.fillNotifiersByList();
			return this._notifiers.concat();
		}
		public function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void{
			if(!this._notifiers) this.fillNotifiersByList();
			var arr:Array = this._notifiers;
			var len:int = this._notifiersLength;
			for(var i:int=0; i<len; i++) arr[i].addEventListener(type, listener, useCapture, priority, useWeakReference);
		} 
		public function dispatchEvent(event:Event):Boolean{
			if(!this._notifiers) this.fillNotifiersByList();
			var arr:Array = this._notifiers;
			var len:int = this._notifiersLength;
			var ret:Boolean = arr[0].dispatchEvent(event);
			if(len>1) for(var i:int=1; i<len; i++) arr[i].dispatchEvent(event);
			return ret;
		} 
		public function hasEventListener(type:String):Boolean{
			if(!this._notifiers) this.fillNotifiersByList();
			return this._notifiersLength>0 ? this._notifiers[0].hasEventListener(type) : false;
		} 
		public function removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void{
			if(!this._notifiers) this.fillNotifiersByList();
			var arr:Array = this._notifiers;
			var len:int = this._notifiersLength;
			for(var i:int=0; i<len; i++) arr[i].removeEventListener(type, listener, useCapture);
		} 
		public function willTrigger(type:String):Boolean{
			if(!this._notifiers) this.fillNotifiersByList();
			return this._notifiersLength>0 ? this._notifiers[0].willTrigger(type) : false;
		}
		protected function fillNotifiersByList():void{
			this._notifiers = new Array();
			var len:int = this._list.length();
			var item:XML;
			for(var i:int=0; i<len; i++){
				item = this._list[i];
				if(item) this._notifiers.push(XMLNotifier.getInstance(item));
			}
			this._notifiersLength = this._notifiers.length;
		}
		override protected function nextName(index:int):String{
			return String(index-1);
		}
		override protected function nextNameIndex(index:int):int{
			return (index<this._list.length()) ? index+1 : 0;
		}
		override protected function nextValue(index:int):*{
			return this._createTree ? this.createCover(this._list[index-1] as XML) : this._list[index-1];
		}
	}
}